AS2: AxisScroller

Posted on
10/10/2007 in AS2 • My Classes

View Example
View Documentation
Download Class & Example Files

Creates a scroller that allows for scrolling in the x or y axis, using the mouse wheel/arrow keys, different easing functions and types, and some other miscellaneous cool things.

PLAIN TEXT
Actionscript:
  1. import mx.utils.Delegate;
  2. import mx.transitions.easing.*;
  3. import mx.transitions.Tween;
  4.  
  5. /**
  6. * Creates a scroller that allows for scrolling in the x or y axis, using the mouse wheel/arrow keys, different easing functions and types, and some other miscellaneous cool things.
  7. *
  8. * @usage
  9. * <code>
  10. * <pre>
  11. import com.reintroducing.ui.AxisScroller;
  13. var optionalObj:Object = new Object({   scrollType: "easing",
  14.                                         isTrackClickable: true,
  15.                                         useArrows: true,
  16.                                         upArrow: content_mc.up_btn,
  17.                                         downArrow: content_mc.down_btn,
  18.                                         easeFunc: Regular.easeOut,
  19.                                         duration: .25,
  20.                                         arrowMove: 100,
  21.                                         scaleScroller: true,
  22.                                         autoHideControls: true});
  24. var scroller:AxisScroller = new AxisScroller(content_mc, content_mc.scroller_mc, content_mc.movie_mc, content_mc.track_mc, content_mc.mask_mc, "y", optionalObj);
  25. * </pre>
  26. * </code>
  27. *
  28. * @author Matt Przybylski [http://www.reintroducing.com]
  29. * @version 1.5
  30. */
  31.  
  32. class com.reintroducing.ui.AxisScroller
  33. {
  34.     /*
  35.      * ====================================================================================================
  36.      * PRIVATE VARIABLES
  37.      * ====================================================================================================
  38.      */
  39.    
  40.     private var _changeProp:String;
  41.     private var _mouseAxis:String;
  42.     private var _changeScale:String;
  43.     private var _nextPosition:Number;
  44.     private var _arrowMove:Number;
  45.     private var _scaleScroller:Boolean;
  46.     private var _autoHideControls:Boolean;
  47.     private var _mouseIsPressedDown:Boolean;
  48.     private var _trackOffset:Number;
  49.     private var _trackStart:Number;
  50.     private var _trackEnd:Number;
  51.     private var _tween:Tween;
  52.     private var _arrow1Tween:Tween;
  53.     private var _arrow2Tween:Tween;
  54.     private var _scrollerTween:Tween;
  55.     private var _trackTween:Tween;
  56.     private var _easeFunc:Function;
  57.     private var _duration:Number;
  58.     private var _holder:MovieClip;
  59.     private var _scroller:MovieClip;
  60.     private var _toBeScrolled:MovieClip;
  61.     private var _track:MovieClip;
  62.     private var _mask:MovieClip;
  63.     private var _axis:String;
  64.     private var _scrollType:String;
  65.     private var _isTrackClickable:Boolean;
  66.     private var _arrows:Boolean;
  67.     private var _upArrow:MovieClip;
  68.     private var _downArrow:MovieClip;
  69.    
  70.     /*
  71.      * ====================================================================================================
  72.      * CONSTRUCTOR
  73.      * ====================================================================================================
  74.      */
  75.    
  76.     /**
  77.      * Creates a new instance of the AxisScroller class.
  78.      *
  79.      * <p>
  80.      * The $optionalParams parameter takes in a couple of values.
  81.      * <ul>
  82.      * <li>scrollType: A string representing the scroll type, "instant" or "easing" (default: "easing")</li>
  83.      * <li>isTrackClickable: A boolean value that makes the track clickable so that you can scroll directly to a certain spot (default: true)</li>
  84.      * <li>useArrows: A boolean value that allows the use of arrow buttons (default: false)</li>
  85.      * <li>upArrow: If useArrows, a movie clip that represents the up arrow button (default: null)</li>
  86.      * <li>downArrow: If useArrows, a movie clip that represents the down arrow button (default: null)</li>
  87.      * <li>easeFunc: A function representing the ease type you'd like to use, as per the Tween class easing functions (default: Regular.easeOut)</li>
  88.      * <li>duration: An integer (in seconds) representing the time that the scrollable content will take to move when easing is used (default: .25)</li>
  89.      * <li>arrowMove: An integer (in pixels) that the scrollable content will move onMouseWheel/Key/Arrow movement (default: 100)</li>
  90.      * <li>autoHideControls: A boolean value that hides the scroller/track/arrows (if applicable) if the scroll content is too small to scroll (default: false)</li>
  91.      * <li>scaleScroller *: A boolean value that allows automatic scaling of the scroll bar (default: false)</li>
  92.      * </ul>
  93.      * * If you use the scaleScroller optional parameter, please make the size of the scroll bar the same size as the track and this will take care of
  94.      * scaling it automatically for you.  If you AREN'T using this parameter, please size your scroll bar accordingly manually.
  95.      * </p>
  96.      *
  97.      * @usage <pre><code>var scroller:AxisScroller = new AxisScroller($holder, $scroller, $toBeScrolled, $track, $mask, $axis, $optionalParams);</code></pre>
  98.      *
  99.      * @param $holder The movie clip (or timeline) that holds all of the other clips corresponding to the scroller
  100.      * @param $scroller The movie clip to be used as the scroller
  101.      * @param $toBeScrolled The movie clip where the scrollable content resides
  102.      * @param $track The movie clip that is used as the track (measures extremes)
  103.      * @param $mask The movie clip that is used as the mask for the scrollable content area
  104.      * @param $axis A string value of either "x" or "y" that determines what axis the content is scrolled along
  105.      * @param $optionalParams Optional parameters to further control the scroller
  106.      */
  107.    
  108.     public function AxisScroller($holder:MovieClip, $scroller:MovieClip, $toBeScrolled:MovieClip, $track:MovieClip, $mask:MovieClip, $axis:String, $optionalParams:Object)
  109.     {
  110.         this._holder                = $holder;
  111.         this._scroller      = $scroller;
  112.         this._toBeScrolled     = $toBeScrolled;
  113.         this._track                     = $track;
  114.         this._mask       = $mask;
  115.         this._axis       = "_" + $axis;
  116.        
  117.         this._scrollType             = ($optionalParams.scrollType == undefined) ? "easing" : $optionalParams.scrollType;
  118.         this._isTrackClickable    = ($optionalParams.isTrackClickable == undefined) ? true : $optionalParams.isTrackClickable;
  119.         this._arrows                = ($optionalParams.useArrows == undefined) ? false : $optionalParams.useArrows;
  120.         this._upArrow           = ($optionalParams.upArrow == undefined) ? null : $optionalParams.upArrow;
  121.         this._downArrow                 = ($optionalParams.downArrow == undefined) ? null : $optionalParams.downArrow;
  122.         this._easeFunc      = ($optionalParams.easeFunc == undefined) ? Regular.easeOut : $optionalParams.easeFunc;
  123.         this._duration      = ($optionalParams.duration == undefined) ? .25 : $optionalParams.duration;
  124.         this._arrowMove                 = ($optionalParams.arrowMove == undefined) ? 100 : $optionalParams.arrowMove;
  125.         this._autoHideControls      = ($optionalParams.autoHideControls == undefined) ? false : $optionalParams.autoHideControls;
  126.         this._scaleScroller    = ($optionalParams.scaleScroller == undefined) ? false : $optionalParams.scaleScroller;
  127.        
  128.         this.manageAxis(this._axis);
  129.         this.init();
  130.     }
  131.    
  132.     /*
  133.      * ====================================================================================================
  134.      * PRIVATE FUNCTIONS
  135.      * ====================================================================================================
  136.      */
  137.    
  138.     // initiates listeners and other events
  139.     private function init():Void
  140.     {
  141.         Mouse.addListener(this);
  142.         Key.addListener(this);
  143.        
  144.         this._holder.onEnterFrame     = Delegate.create(this, manageScrolling);
  145.        
  146.         this.activateButtonEvents();
  147.     }
  148.    
  149.     // re-activates the button events
  150.     private function activateButtonEvents():Void
  151.     {
  152.         this._scroller.onPress     = Delegate.create(this, manageMouseDown);
  153.        
  154.         this._scroller.onRelease = this._scroller.onReleaseOutside = Delegate.create(this, manageMouseUp);
  155.         this._scroller.useHandCursor = true;
  156.        
  157.         if (this._isTrackClickable)
  158.         {
  159.             this._track.onRelease       = Delegate.create(this, manageTrack);
  160.             this._track.useHandCursor      = true;
  161.         }
  162.        
  163.         if (this._arrows)
  164.         {
  165.             this._upArrow.onRelease         = Delegate.create(this, manageUpArrow);
  166.             this._downArrow.onRelease     = Delegate.create(this, manageDownArrow);
  167.            
  168.             this._downArrow.useHandCursor = this._upArrow.useHandCursor = true;
  169.         }
  170.     }
  171.    
  172.     // destroys the events on the buttons
  173.     private function killButtonEvents():Void
  174.     {
  175.         this._scroller.onPress = this._scroller.onRelease = this._scroller.onReleaseOutside = null;
  176.         this._scroller.useHandCursor = false;
  177.        
  178.         if (this._isTrackClickable)
  179.         {
  180.             this._track.onRelease = null;
  181.             this._track.useHandCursor = false;
  182.         }
  183.        
  184.         if (this._arrows)
  185.         {
  186.             this._upArrow.onRelease = this._downArrow.onRelease = null;
  187.             this._upArrow.useHandCursor = this._downArrow.useHandCursor = false;
  188.         }
  189.     }
  190.    
  191.     // sets the axis at which the scroller will function against
  192.     private function manageAxis($axis:String):Void
  193.     {
  194.         if ($axis == "_x")
  195.         {
  196.             this._changeProp          = "_width";
  197.             this._mouseAxis             = "_xmouse";
  198.             this._changeScale         = "_xscale";
  199.         }
  200.         else if ($axis == "_y")
  201.         {
  202.             this._changeProp          = "_height";
  203.             this._mouseAxis             = "_ymouse";
  204.             this._changeScale         = "_yscale";
  205.         }
  206.        
  207.         this._trackOffset         = - (this._scroller[this._changeProp] / 2);
  208.     }
  209.    
  210.     // calculates values and responds to changes by the scroller
  211.     private function manageScrolling():Void
  212.     {
  213.         var trackSize:Number          = this._track[this._changeProp];
  214.         var trackStart:Number       = this._track[this._axis];
  215.         var trackEnd:Number             = this._track[this._axis] + trackSize - (this._scroller[this._changeProp]);
  216.         var trackRange:Number       = trackEnd - trackStart;
  217.         var maskSize:Number             = this._mask[this._changeProp];
  218.         var movieSize:Number          = this._toBeScrolled[this._changeProp];
  219.         var minPosition:Number    = this._mask[this._axis] + 2;
  220.         var maxPosition:Number    = minPosition + movieSize - maskSize + 4;
  221.         var onePercentChange:Number     = (maxPosition - minPosition) / 100;
  222.         var percent:Number     = Math.round(((this._scroller[this._axis] - trackStart) / trackRange) * 100);
  223.         var targetPosition:Number     = Math.round(minPosition - (onePercentChange * percent));
  224.        
  225.         this._trackStart             = trackStart;
  226.         this._trackEnd      = trackEnd;
  227.        
  228.         if (this._scrollType == "instant")
  229.         {
  230.             this._toBeScrolled[this._axis] = targetPosition;
  231.         }
  232.         else if (this._scrollType == "easing")
  233.         {
  234.             this._toBeScrolled[this._axis] += Math.round((targetPosition - this._toBeScrolled[this._axis]) / 5);
  235.         }
  236.  
  237.         if (movieSize <maskSize)
  238.         {
  239.             onePercentChange = 0;
  240.         }
  241.        
  242.         if (this._mouseIsPressedDown)
  243.         {
  244.             this._scroller[this._axis] = Math.round(this._holder[this._mouseAxis] - (this._scroller[this._changeProp] / 2));
  245.         }
  246.        
  247.         if (this._scroller[this._axis] <trackStart)
  248.         {
  249.             this._scroller[this._axis] = Math.round(trackStart);
  250.         }
  251.         else if (this._scroller[this._axis]> trackEnd)
  252.         {
  253.             this._scroller[this._axis] = Math.round(trackEnd);
  254.         }
  255.        
  256.         if (this._scaleScroller) this.manageScrollScaling(movieSize, maskSize);
  257.        
  258.         this.manageControls(this._autoHideControls, movieSize, maskSize);
  259.     }
  260.    
  261.     // regulates mouse pressed down
  262.     private function manageMouseDown():Void
  263.     {
  264.         this._mouseIsPressedDown = true;
  265.     }
  266.    
  267.     // regulates mouse released
  268.     private function manageMouseUp():Void
  269.     {
  270.         this._mouseIsPressedDown = false;
  271.     }
  272.    
  273.     // regulates the movement of the content based on where the track is clicked, if applicable
  274.     private function manageTrack():Void
  275.     {
  276.         if (this._isTrackClickable)
  277.         {
  278.             if (this._scrollType == "instant")
  279.             {
  280.                 if (this._holder[this._mouseAxis] <this._trackStart)
  281.                 {
  282.                     this._scroller[this._axis] = this._trackStart;
  283.                 }
  284.                 else if (this._holder[this._mouseAxis]> this._trackEnd)
  285.                 {
  286.                     this._scroller[this._axis] = this._trackEnd;
  287.                 }
  288.                 else
  289.                 {
  290.                     this._scroller[this._axis] = Math.round(this._holder[this._mouseAxis] - (this._scroller[this._changeProp] / 2));
  291.                 }
  292.             }
  293.             else if (this._scrollType == "easing")
  294.             {
  295.                 if (this._holder[this._mouseAxis] <this._trackStart)
  296.                 {
  297.                     this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._trackStart, this._duration, true);
  298.                 }
  299.                 else if (this._holder[this._mouseAxis]> this._trackEnd)
  300.                 {
  301.                     this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._trackEnd, this._duration, true);
  302.                 }
  303.                 else
  304.                 {
  305.                     this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], Math.round(this._holder[this._mouseAxis] - (this._scroller[this._changeProp] / 2)), this._duration, true);
  306.                 }
  307.             }
  308.         }
  309.     }
  310.    
  311.     // regulates the movement of the up arrow, if applicable
  312.     private function manageUpArrow():Void
  313.     {
  314.         if (this._scrollType == "instant")
  315.         {
  316.             this._nextPosition = Math.round(this._scroller[this._axis] - this._arrowMove);
  317.            
  318.             if (this._nextPosition <this._trackStart)
  319.             {
  320.                 this._scroller[this._axis] = this._trackStart;
  321.             }
  322.             else
  323.             {
  324.                 this._scroller[this._axis] = this._nextPosition;
  325.             }
  326.         }
  327.         else if (this._scrollType == "easing")
  328.         {
  329.             this._nextPosition = Math.round(this._scroller[this._axis] - this._arrowMove);
  330.            
  331.             if (this._nextPosition <this._trackStart)
  332.             {
  333.                 this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._trackStart, this._duration, true);
  334.             }
  335.             else
  336.             {
  337.                 this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._nextPosition, this._duration, true);
  338.             }
  339.         }
  340.     }
  341.    
  342.     // regulates the movement of the down arrow, if applicable
  343.     private function manageDownArrow():Void
  344.     {
  345.         if (this._scrollType == "instant")
  346.         {
  347.             this._nextPosition = Math.round(this._scroller[this._axis] + this._arrowMove);
  348.            
  349.             if (this._nextPosition> this._trackEnd)
  350.             {
  351.                 this._scroller[this._axis] = this._trackEnd;
  352.             }
  353.             else
  354.             {
  355.                 this._scroller[this._axis] = this._nextPosition;
  356.             }
  357.         }
  358.         else if (this._scrollType == "easing")
  359.         {
  360.             this._nextPosition = Math.round(this._scroller[this._axis] + this._arrowMove);
  361.            
  362.             if (this._nextPosition> this._trackEnd)
  363.             {
  364.                 this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._trackEnd, this._duration, true);
  365.             }
  366.             else
  367.             {
  368.                 this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._nextPosition, this._duration, true);
  369.             }
  370.         }
  371.     }
  372.    
  373.     // auto hides/shows the controls of the scroller
  374.     private function manageControls($isAutoHideEnabled:Boolean, $contentSize:Number, $maskSize:Number):Void
  375.     {
  376.         if ($isAutoHideEnabled && $contentSize <= $maskSize)
  377.         {
  378.             // yes, hide controls
  379.             this._arrow1Tween   = new Tween(this._upArrow, "_alpha", this._easeFunc, this._upArrow._alpha, 0, this._duration, true);
  380.             this._arrow2Tween   = new Tween(this._downArrow, "_alpha", this._easeFunc, this._downArrow._alpha, 0, this._duration, true);
  381.             this._scrollerTween = new Tween(this._scroller, "_alpha", this._easeFunc, this._scroller._alpha, 0, this._duration, true);
  382.             this._trackTween    = new Tween(this._track, "_alpha", this._easeFunc, this._track._alpha, 0, this._duration, true);
  383.            
  384.             this.killButtonEvents();
  385.         }
  386.         else
  387.         {
  388.             // no, show controls
  389.             this._arrow1Tween   = new Tween(this._upArrow, "_alpha", this._easeFunc, this._upArrow._alpha, 100, this._duration, true);
  390.             this._arrow2Tween   = new Tween(this._downArrow, "_alpha", this._easeFunc, this._downArrow._alpha, 100, this._duration, true);
  391.             this._scrollerTween = new Tween(this._scroller, "_alpha", this._easeFunc, this._scroller._alpha, 100, this._duration, true);
  392.             this._trackTween    = new Tween(this._track, "_alpha", this._easeFunc, this._track._alpha, 100, this._duration, true);
  393.            
  394.             this.activateButtonEvents();
  395.         }
  396.     }
  397.    
  398.     // regulates the scaling of the scroller, if applicable
  399.     private function manageScrollScaling($contentSize:Number, $maskSize:Number):Void
  400.     {
  401.         var trackPercent:Number = Math.ceil(($maskSize / $contentSize) * 100);
  402.        
  403.         if ($contentSize> $maskSize)
  404.         {
  405.             this._scroller[this._changeScale] = trackPercent;
  406.         }
  407.         else
  408.         {
  409.             this._scroller[this._changeScale] = 100;
  410.         }
  411.     }
  412.    
  413.     // regulates the movement of the mouse wheel
  414.     private function onMouseWheel($delta:Number):Void
  415.     {
  416.         var multiplier:Number = 10;
  417.        
  418.         if (this._scrollType == "instant")
  419.         {
  420.             this._nextPosition = Math.round(this._scroller[this._axis] - ($delta * multiplier));
  421.            
  422.             if (this._nextPosition <this._trackStart)
  423.             {
  424.                 this._scroller[this._axis] = this._trackStart;
  425.             }
  426.             else if (this._nextPosition> this._trackEnd)
  427.             {
  428.                 this._scroller[this._axis] = this._trackEnd;
  429.             }
  430.             else
  431.             {
  432.                 this._scroller[this._axis] = this._nextPosition;
  433.             }
  434.         }
  435.         else if (this._scrollType == "easing")
  436.         {
  437.             this._nextPosition = Math.round(this._scroller[this._axis] - ($delta * multiplier));
  438.            
  439.             if (this._nextPosition <this._trackStart)
  440.             {
  441.                 this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._trackStart, this._duration, true);
  442.             }
  443.             else if (this._nextPosition> this._trackEnd)
  444.             {
  445.                 this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._trackEnd, this._duration, true);
  446.             }
  447.             else
  448.             {
  449.                 this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._nextPosition, this._duration, true);
  450.             }
  451.         }
  452.     }
  453.    
  454.     // regulates the movement of the up and down keyboard keys
  455.     private function onKeyDown():Void
  456.     {
  457.         switch(Key.getCode())
  458.         {
  459.             case 38: // up
  460.                 if (this._scrollType == "instant")
  461.                 {
  462.                     this._nextPosition = Math.round(this._scroller[this._axis] - this._arrowMove);
  463.                    
  464.                     if (this._nextPosition <this._trackStart)
  465.                     {
  466.                         this._scroller[this._axis] = this._trackStart;
  467.                     }
  468.                     else
  469.                     {
  470.                         this._scroller[this._axis] = this._nextPosition;
  471.                     }
  472.                 }
  473.                 else if (this._scrollType == "easing")
  474.                 {
  475.                     this._nextPosition = Math.round(this._scroller[this._axis] - this._arrowMove);
  476.                    
  477.                     if (this._nextPosition <this._trackStart)
  478.                     {
  479.                         this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._trackStart, this._duration, true);
  480.                     }
  481.                     else
  482.                     {
  483.                         this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._nextPosition, this._duration, true);
  484.                     }
  485.                 }
  486.                 break;
  487.                
  488.             case 40: // down
  489.                 if (this._scrollType == "instant")
  490.                 {
  491.                     this._nextPosition = Math.round(this._scroller[this._axis] + this._arrowMove);
  492.                    
  493.                     if (this._nextPosition> this._trackEnd)
  494.                     {
  495.                         this._scroller[this._axis] = this._trackEnd;
  496.                     }
  497.                     else
  498.                     {
  499.                         this._scroller[this._axis] = this._nextPosition;
  500.                     }
  501.                 }
  502.                 else if (this._scrollType == "easing")
  503.                 {
  504.                     this._nextPosition = Math.round(this._scroller[this._axis] + this._arrowMove);
  505.                    
  506.                     if (this._nextPosition> this._trackEnd)
  507.                     {
  508.                         this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._trackEnd, this._duration, true);
  509.                     }
  510.                     else
  511.                     {
  512.                         this._tween = new Tween(this._scroller, this._axis, this._easeFunc, this._scroller[this._axis], this._nextPosition, this._duration, true);
  513.                     }
  514.                 }
  515.                 break;
  516.         }
  517.     }
  518.    
  519.     /*
  520.      * ====================================================================================================
  521.      * PUBLIC FUNCTIONS
  522.      * ====================================================================================================
  523.      */
  524.    
  525.     /**
  526.      * Creates the scroller again if it was deleted using destroy.
  527.      *
  528.      * @usage <pre><code>scroller.create();</code></pre>
  529.      *
  530.      * @return Nothing
  531.      */
  532.    
  533.     public function create():Void
  534.     {
  535.         this.init();
  536.     }
  537.    
  538.     /**
  539.      * Clears the enterFrame and removes the listeners/events.
  540.      *
  541.      * @usage <pre><code>scroller.destroy();</code></pre>
  542.      *
  543.      * @return Nothing
  544.      */
  545.    
  546.     public function destroy():Void
  547.     {
  548.         delete this._holder.onEnterFrame;
  549.         Mouse.removeListener(this);
  550.         Key.removeListener(this);
  551.        
  552.         this.killButtonEvents();
  553.     }
  554.    
  555.     /*
  556.      * ====================================================================================================
  557.      * GETTERS & SETTERS
  558.      * ====================================================================================================
  559.      */
  560.    
  561.     /**
  562.      * Gets the value of autoHideControls to see if they are currently being hidden or not.
  563.      *
  564.      * @usage <pre><code>trace(scroller.autoHideControls);</code></pre>
  565.      */
  566.    
  567.     public function get autoHideControls():Boolean
  568.     {
  569.         return this._autoHideControls;
  570.     }
  571.    
  572.     /**
  573.      * Sets the value of autoHideControls "on-the-fly".
  574.      *
  575.      * @usage <pre><code>scroller.autoHideControls = true;</code></pre>
  576.      */
  577.    
  578.     public function set autoHideControls($b:Boolean):Void
  579.     {
  580.         this._autoHideControls = $b;
  581.     }
  582.    
  583.     /*
  584.      * ====================================================================================================
  585.      * CLOSE CLASS
  586.      * ====================================================================================================
  587.      */
  588. }

, , ,

If you found this post useful, please consider leaving a comment, subscribing to the feed, or making a small donation.

7 Comments
Comment by maxgrafx on October 14, 2007 @ 2:55 PM

i really like this class, but instantly i thought can i use both axisses on a movieClip.
i tried it but i didn't seem te get it working.

is there a way?

Br,

Max

Comment by Matt Przybylski on October 14, 2007 @ 3:22 PM

When making the class originally, it was not intended to work on both axis, sorry. It is not possible to do with the way the class is set up because you'd have to have two of everything (tracks, scrollers, etc) and originally it was not anticipated. What you could do though, however, and i haven't tried this, is set up two instances of it, one horizontal and one vertical, and just use the same movieclip/mask as the clips to scroll.

let me know if that works out.

Comment by maxgrafx on October 17, 2007 @ 4:30 AM

hehe, tried that. it doesn't work

Comment by Matt Przybylski on October 17, 2007 @ 7:36 AM

when i get a bit of time here in the near future i'll try to see if i can come up with a solution.

Comment by Digitalrox on March 9, 2009 @ 7:55 AM

Thanx man. It saved me a lot of time.

Comment by Digitalrox on March 9, 2009 @ 7:58 AM

Thanx man. It saved me a lot of time. I'm already working with AS3 and Flex. An application of my client is based on AS2.

Comment by Ishfaak on October 4, 2011 @ 3:49 AM

I really Loved this Class. Was very useful, this superseded all the classes with the .js functions, that liberated it self from conflicts.

Cheers.

Leave a comment

(required)

(required)